J. Schray, R. W. Tucker, C. H. T. Wang, in Clifford Algebras with numeric and symbolic computations, R. Ablamowicz, P. Lounesto, J.M. Parra (eds.), (Birkhauser, Boston, 1996)
LUCY: A CLIFFORD ALGEBRA APPROACH TO SPINOR CALCULUS J¨org Schray1 , Robin W Tucker 2 , Charles Wang
3
Department of Physics Lancaster University, Lancaster LA1 4YB, UK
Abstract LUCY is a MAPLE program that exploits the general theory of Clifford algebras to effect calculations involving real or complex spinor algebra and spinor calculus on manifolds in any dimension. It is compatible with MAPLE V Release 5 and incorporates a number of valuable facilities such as multilinearity of the Clifford product and the freedom to adopt arbitrary bases in which to perform calculations. The user can also pass with ease between the purely (real or complex) Clifford algebraic language and the more familiar matrix language. LUCY enables one to explore the structure of spinor covariant derivatives on flat or curved spaces and correlate the various spinorinner products with the basic involutions of the underlying Clifford algebra. The canonical spinor covariant derivative is based on the Levi-Civita connection and a facility for the computation of connection coefficients has also been included. A self-contained account of the facilities available is provided together with a description of the syntax, illustrative examples for each procedure and a brief survey of the algorithms that are used in the program.
Keywords Clifford Algebra, Spinor, Spinor Adjoint, Spinor Inner Product, Spinor Covariant Derivative, Dirac Operator, MAPLE, Matrix Representations.
1
[email protected] [email protected] 3
[email protected] 2
1
1. Introduction Of the various methods used by physicists for describing spinors the approach using the theory of Clifford algebras offers a comprehensive and unifying language. This approach is also ideally suited for describing the action of the (pseudo-)orthogonal groups in any dimension and therefore provides a natural framework for relativistic theories including gravitation. LUCY is a MAPLE program that enables the user to exploit this language at both the teaching and research level. It incorporates a number of valuable facilities such as multilinearity of the Clifford product and the freedom to adopt arbitrary bases in which to perform calculations. The user can also pass with ease between the purely (real or complex) Clifford algebraic language and the more familiar matrix language. LUCY enables one to explore the structure of spinor covariant derivatives on flat or curved spaces and correlate the various spinor-inner products with the basic involutions of the underlying Clifford algebra. The canonical spinor covariant derivative is based on the Levi-Civita connection and a facility for the computation of connection coefficients has also been included. Since there already exist MAPLE packages for exterior algebras, LUCY is restricted to Clifford algebras although to fully appreciate the Clifford approach to differential geometry the experienced user may wish to integrate LUCY with the theory of differential forms [1]. The following is a self-contained account of the facilities available together with a description of the syntax, illustrative examples for each procedure and a brief survey of the algorithms adopted in the program. The program is compatible with MAPLE V Release 5. The basic theory and notation follows that of [1].
2
2. Clifford Algebra Let {ea } be a basis for an n-dimensional vector space V over R or C with a symmetric inner-product (metric) g, such that the metric components in this basis are g ab = g(ea , eb ). Suppose the frame indices {a} are enumerated in the integer range u, u + 1, · · · , w with w = u + n − 1. The algebraic rules for the associated 2n -dimensional Clifford algebra C`(V, g) may be established with the command: Cliffordsetup( u .. w , {(a1 , b1 ) = g a1 b1 , (a2 , b2 ) = g a2 b2 , · · · }, e ) . The indexed names e[u], e[u + 1], · · · , e[w] are now available to the user and denote the “ambient” basis vectors for any chosen root name e. A symbol in the square brackets [] after a root name for a basis element corresponds to an “upper” index. In the second argument, only non-zero and either (ai , bj ) or (bj , ai ) metric components need to be specified. Example 1 The following command sets up a 2-dimensional vector space with Lorentzian orthonormal basis { e0 , e1 } in which the metric has components diag(−1, 1). >
Cliffordsetup(0..1,{(0,0)=-1,(1,1)=1},e);
Clifford scalars are recognised by LUCY as expressions independent of basis vectors. It recognizes an expression x as a vector (x ∈ V ) if it is a linear combination of the basis vectors. Clifford multiplication between vectors is carried out with the multi-argument associative linear operator &v which first distributes over addition and factors out scalars. 4 In the following text we shall simply use juxtaposition of symbols to denote such Clifford multiplication. Basis vectors are ordered by LUCY using the anticommutation relation: ea eb + eb ea = 2g ab (1) to obtain a canonical form of any Clifford element (chosen in this program to be sums of products of basis vectors with increasing indices). The unevaluated ea1 ea2 ea3 . . . (a1 < a2 < a3 . . .) together with the basis vectors and the number 1 form a basis for the Clifford algebra and a linear combination of 4
The name of this operator is motivated by the symbol ∨ which is commonly used to denote the operation of Clifford multiplication.
3
these basis elements ω is treated as a Clifford element (ω ∈ C`(g, V )). A complete list of the ambient basis vectors and their canonically ordered Clifford products is returned with the command Cliffordbasis(). A simplification procedure bcollect is provided in this program taking any expression as argument and returning an equivalent expression with Clifford basis elements collected into a canonical order and their coefficients simplified. Optionally bcollect accepts a MAPLE or user-defined function as second argument, which may be applied to the coefficients of the collected terms. Example 2 Following Example 1, one can perform the following calculations: > Cliffordbasis(); [e0 , e1 , e0 &v e1 ] > h:=(c1*e[0]-c2*e[1]) &v (c2*e[0]+(c1+2*c2)*e[1]); h := c1 (−c2 + (c1 + 2 c2 ) (e0 &v e1 )) − c2 (−c2 (e0 &v e1 ) + c1 + 2 c2 ) > bcollect(h); (c1 2 + 2 c1 c2 + c2 2 ) (e0 &v e1 ) − 2 c1 c2 − 2 c2 2 > bcollect(h,factor); (c1 + c2 )2 (e0 &v e1 ) − 2 c2 (c1 + c2 ) Two involutions and an anti-involution 5 on C` are available in this program. The main anti-involution (reversion involution) ξ on the Clifford algebra is denoted by the linear unary operator &xi. It maps a scalar or a vector to itself but reverses the order of elements in a Clifford product. However, one will not see a reversed &v product on output, since &v canonically reorders factors using the anticommutation relation (1). The main involution (grade involution) η is performed with the linear unary operator &eta. Acting on a Clifford product of k vectors it multiplies such a Clifford element by (−1)k . Complex conjugation ∗ is represented by√the conjugate linear unary √ operator &aster, which effects the substitution −1 → − −1 , i.e. &aster naively regards all names or functions as real except for the symbolic primitive idempotent which will be discussed later. 5
A number of alternative notations exist for these operations. We have chosen to use the two maps ξ and η to facilitate readability of the output from LUCY. The following relations offer a translation to other alternative notations: ω η = ω ˆ , ωξ = ω ˜ and ω ξη = ω ¯ where ω ∈ C`(g, V ).
4
Example 3 Following Examples 1 and 2, we can compute: > x:=I*c1+c2*e[0]+I*c3*e[1]+c4*e[0] &v e[1]: > &eta x; c1 I − c2 e0 − c3 e1 I + c4 (e0 &v e1 ) > &xi x; c1 I + c2 e0 + c3 e1 I − c4 (e0 &v e1 ) > &aster x; −c1 I + c2 e0 − c3 e1 I + c4 (e0 &v e1 ) LUCY accepts elements that belong to the dual space V ∗ . They must be expanded in a basis known to the program. If one designates {Xa } to be a basis naturally dual to {ea }, i.e. ea (Xb ) = δ a b in terms of the Kronecker symbol, then call Cliffordsetup with the chosen root name X labelling the ambient dual basis, as an extra fourth argument: Cliffordsetup( u .. w , {(a1 , b1 ) = g a1 b1 , (a2 , b2 ) = g a2 b2 , · · · }, e , X ) together with all other arguments as explained previously. This defines the indexed names X[{u}], X[{u + 1}], · · ·, X[{w}] to be elements of the ambient dual basis. Subsequently a linear combination of dual basis vectors Y is recognized as a dual vector (Y ∈ V ∗ ). Clifford scalars are recognised by LUCY as expressions independent of both basis and dual basis vectors. The superscript-subscript convention adopted by LUCY is that each lower frame index is an integer enclosed with [{}], while each upper frame index is an integer enclosed with []. Hence X[{a}], X[b], e[a] and e[{a}] &v e[b] are understood as Xa , X b , ea and ea eb respectively, where X a = g ab Xb and ea = gab eb (g ac gcb = δ a b ) as usual. Here a, b, c are integers within the frame enumeration range and e, X the root names of the ambient basis and dual basis respectively. (The Einstein summation convention for indices is adopted throughout this text.) The facilities convert( expr , up ) or convert( expr , down ) are provided for raising or lowering frame indices on demand. The first command replaces all ea , Xa appearing in the expression expr with gab eb , gab X b and conversely the second command replaces all ea , X a with g ab eb , g ab Xb respectively. Both { 1, ea , eb , · · · , ea eb , · · · } and { 1, ea , eb , · · · , ea eb , · · · } provide a basis for C`(V, g). Excluding the number 1, the former Clifford basis elements are accessible from Cliffordbasis(up) (or equivalently Cliffordbasis() introduced in the last section) while the latter set can be obtained with Cliffordbasis(down). 5
Example 4 As an extension to Example 1, by specifying the dual frame root name X, the following computation can be executed: > Cliffordsetup(0..1,{(0,0)=-1,(1,1)=1},e,X); > convert(X[{0}],up); −X0 > convert(%,down); X{0} > e[{0}] &v e[0]; 1 > cb:=Cliffordbasis(down); cb := [e{0} , e{1} , e{0} &v e{1} ] > w:=k0+convert([seq((k||i)*cb[i],i=1..nops(cb))],‘+‘); w := k0 + k1 e{0} + k2 e{1} + k3 (e{0} &v e{1} ) > u:=convert(w,up); u := k0 − k1 e0 + k2 e1 − k3 (e0 &v e1 )
The interior product (contraction) iY z between any dual vector Y and Clifford element z can be performed with the linear binary operator &i with the call &i(Y, z). It returns 0 if the second argument is a scalar. Contraction between naturally dual basis elements produces 1 or 0 according to whether the frame indices are equal or not. &i defines a graded derivation on Clifford products and it acts on &v terms as follows: Y &i &v(x, y, z, · · · ) yields ( Y &i x)* &v(y, z, · · · ) − x &v (Y &i &v (y, z, · · · )), for Y ∈ V ∗ and x, y, z ∈ V . The second term has a similar structure to the original expression; the same procedure is then applied repeatedly until the expansion is completed.
6
Example 5 Following Example 4, we can calculate: > X[{0}] &i e[0]; 1 > X[{0}] &i e[{0}]; −1 > (a0*X[{0}] + a1*X[{1}]) &i u ; −a0 k1 − a0 k3 e1 + a1 k2 + a1 k3 e0 Rather than using the (contravariant) metric components g ab = g(ea , eb ) when specifying the metric, one can equally well use the covariant metric components with the command: Cliffordsetup( u .. w , {({a1 }, {b1 }) = ga1 b1 , ({a2 }, {b2 }) = ga2 b2 , · · · }, e , X ) where gab are defined by g ac gcb = δ a b such that gab = g ∗ (Xa , Xb ) in which g ∗ is the induced metric on V ∗ .
7
3. Clifford Calculus The program is also capable of setting up the Clifford algebra of the cotangent space associated with a variable point p of a patch of an n-dimensional manifold M . If g is the (covariant) metric tensor field on M we identify V with the cotangent space T∗p M , V ∗ with the tangent space Tp M and g ∗ with g |p at any point p on M . In this sense we will also call elements in V covectors and elements in V ∗ tangent vectors. Such a setup is initiated by using one of the following two commands: Cliffordsetup( u .. w , {(a1 , b1 ) = g a1 b1 , (a2 , b2 ) = g a2 b2 , · · · }, e , X , {hcobase eqnsi} ) Cliffordsetup( u .. w , {({a1 }, {b1 }) = ga1 b1 , ({a2 }, {b2 }) = ga2 b2 , · · · }, e , X , {hcobase eqnsi} ) using the previously defined conventions. The new parameter hcobase eqnsi is a sequence of n equations expressing each cobase vector in terms of “formal” coordinate differentials. If the names x1 , x2 , . . . are to be regarded as local coordinates on the patch, then {d(x1 ), d(x2 ), · · · } syntactically stands for a local coordinate coframe. Each equation in hcobase eqnsi has a cobase vector ea as the left hand side and a linear combination of the d(xi ), with functions of the coordinates as coefficients, on the right hand side. The metric components may also be functions of the coordinates. With such a calling sequence, Cliffordsetup returns a set of equations giving the reciprocal relations for d(xi )in terms of linear combinations of ea .
8
Example 6 The following sets up a spacetime patch with local coordinates { u, v, x, y }, a partially null coframe {na } and a plane wave metric g = n1 ⊗ n2 + n2 ⊗ n1 +n3 ⊗n3 +n4 ⊗n4 corresponding to the infinitesimal arc length squared ds2 = H(u, x, y) du du + 2 du dv + dx dx + dy dy. > alias(H=H_(u,x,y)): > Cliffordsetup(1..4,{({1},{2})=1,({3},{3})=1,({4},{4})=1 > >
>
>
},n,Z, { n[1]=d(u), n[2]=d(v) + H/2*d(u), n[3]=d(x),n[4]=d(y) }); 1 {d(u) = n1 , d(v) = n2 − H n1 , d(x) = n3 , d(y) = n4 } 2 n[2] &v n[1]; 2 − (n1 &v n2 ) convert(%,down); n{1} &v n{2}
For any tangent vector fields (i.e. linear combinations of dual basis vectors from the ambient frame with functions of the coordinates as coefficients), X, Y and Clifford element α (which may be a linear combination of covectors from the ambient coframe with functions of the coordinates as coefficients), the covariant derivatives ∇X Y and ∇X α with respect to the Levi-Civita (pseudo-)Riemannian connection ∇ induced by g, are respectively computed with the commands X &C Y and X &C α, or &C(X, Y ) and &C(X, α). The binary operator &C is function-linear in its first argument while it is distributive over addition in the second argument. The Leibnitz rule X &C (f Λ) = X(f ) Λ + f (X &C Λ) is activated for any function f of the coordinates and tangent vector or Clifford element Λ. For a Clifford product of the ambient cobase vectors, α = y z · · · , X &C α yields (X &C y) &v z &v · · · + y &v (X &C z) &v · · · + · · · since the connection is compatible with the metric. After this expansion, the remaining covariant derivatives of the ambient cobase or dual basis vectors are automatically computed by LUCY in terms of the connection coefficients Γc ba defined by: ∇Xa Xb = Γc ba Xc ,
∇Xa ec = −Γc ba eb .
(2)
The command RIEMCONNEX() returns the table containing these connection coefficients Γa bc with indices [a,{b},{c}] (as well as Γabc ≡ gad Γd bc with indices [{a},{b},{c}]) for integers a, b, c within the frame enumeration range. 9
Example 7 Continuing from the setup in Example 6 where the vector field Z1 is ∂ . It naturally dual to n1 = du, Z1 represents the direction derivative ∂u follows that ∇Z1 H = Z1 (H) = ∂H as verified below: ∂u > Z[{1}] &C H; ∂ ∂u >
>
> >
>
H
Z[{1}] &C Z[{4}]; 1 ∂ ( H) Z{2} 2 ∂y Z[2] &C (n[1] &v n[2] &v n[3] &v n[4]); 1 ∂ 1 ∂ ( ∂x H) (n1 &v n4 ) − ( ∂y H) (n1 &v n3 ) 2 2 Gamma:=RIEMCONNEX(): Gamma[2,{4},{1}]; 1 ∂ ( H) 2 ∂y Gamma[{1},{2},{3}]; 0
10
4. Spinor Modules Within a Clifford algebra framework spinors may be represented by Clifford elements lying in some minimal left ideal projected by a primitive idempotent [1]. A Clifford element P is an idempotent if P P = P , and is primitive if P cannot be expressed as a sum of idempotents. However the expansion of such an element of C` P in a Clifford basis is typically a sum of as many terms as the dimension of the Clifford algebra which exceeds the dimension of the spinor space. Such inefficiency can be circumvented by keeping P symbolic in computation. Let s be the dimension of any left minimal left module C` P . We can choose Clifford elements α1 , α2 , . . . , αs from the ambient Clifford basis such that {αi P } spans C` P . By specifying the multiplication rules for any ambient Clifford basis Ps element acting on a symbolic P from the left one can convert ω P into i=1 fi (αi P ) which has less summands, for any ω ∈ C` and some scalars fi . In the same fashion one can find elements βP 1 , β2 , . . . , βs such that {P βi } spans a right module P C` and write P ω = i hi (P βi ), for any ω ∈ C` and some scalars hi . The Clifford elements {αi } and {βi } are called the left and right kernel elements respectively. Although the algorithm used by LUCY can be generalised, in the following implementation it will be assumed that C` is simple and P C` P is 1-dimensional so that one can further compute P {left and right kernels} P to get the rules for converting P ω P into a real or complex number times P for any ω ∈ C` . This is the case for V even dimensional where the complexified C` (V, g) is isomorphic to an s × s complex matrix algebra, i.e. C` (V, g) ' Mat(s, C). By equating dim(C` ) = 2n with dim(Mat(s, C)) = s2 , in this case the dimension of the n spinor space is readily seen to be s = 2 2 . In LUCY the command Spinorsetup chooses such a symbolic primitive idempotent and returns a list of two lists. The first list contains the chosen left kernels and the second contains the chosen right kernels. 1 is included n as the first chosen kernel in both lists. The length of each list should be 2 2 if P is primitive. The program informs the user if this condition is violated. Spinorsetup can be called in two forms. Given an explicit form of a primitive idempotent hP expri (in terms of the basis elements accessible from either Cliffordbasis(up) or Cliffordbasis(down)), the command Spinorsetup( P = hP expri) defines any symbol P to carry the algebraic property of hP expri. It is then much more efficient to use P instead of hP expri in subsequent computations. The system recognizes a Clifford element ψ as a spinor (ψ ∈ C` P ) if ψ is a 11
linear combination of &v(· · · , P ) terms. Likewise a Clifford element φ is recognized as a dual spinor (φ ∈ P C` ) if φ is a linear combination of &v(P, · · ·) terms. P itself may be regarded as either a spinor or a dual spinor. Spinor or dual spinor basis elements are collected and their coefficients simplified by evaluating bcollect on any (dual) spinor. On some occasions one may wish to bring the symbolic P in any expression expr back to its explicit form. expandP(expr) is the command for this purpose. Example 8 Following Examples 6 and 7 one can issue the following commands: > PP:=1/4*(n[1] &v n[2]) &v (1+n[3]): > PP &v PP - PP; 0 > Spinorsetup(P=PP); [[1, n2 , n4 , n2 &v n4 ], [1, n1 , n4 , n1 &v n4 ]] > (H + sin(v)^2*n[2] - n[3] + cos(v)^2*n[2] &v n[3]) &v P; H P + sin(v)2 (n2 &v P ) − P + cos(v)2 (n2 &v P ) > bcollect(%); (n2 &v P ) + (H − 1) P > w:=H*n[1] + n[1] &v n[2]: > wP:=w &v P; wP := 2 P > Pw:=P &v w; Pw := H (P &v n1 ) + 2 P > wPw:=wP &v Pw; wPw := 2 H (P &v n1 ) + 4 P > bcollect(expandP(wPw)); H n1 − H (n1 &v n3 ) + (n1 &v n2 ) + &v(n1 , n2 , n3 ) If the ambient coframe is orthogonal, i.e. the matrix of metric components used in Cliffordsetup is diagonal, one can alternatively call Spinorsetup with any chosen symbol P : Spinorsetup(P ) and the system will automatically generate a choice of a primitive idempotent. In this case, the selected explicit Clifford element that P stands for is returned by calling expandP(P ). 12
Example 9 The following sets up a local Clifford structure on a 2-dimensional de Sitter space-time with the orthogonal coordinate coframe {e0 = dt, e1 = dx}. > Cliffordsetup(0..1,{({0},{0})=-1,({1},{1})=exp(4*k*t)},e,X, > {e[0]=d(t),e[1]=d(x)}): > Spinorsetup(P); [[1, e1 ], [1, e1 ]] > expandP(P); 1 1 + I e0 2 2 The differential relations induced by the idempotency of P are also encoded into the program. Thus for any tangent vector field Y , evaluation of Y &C P leads to a sum of spinors and dual spinors: ∇Y P = ∇Y (P P ) = ∇Y P P + P ∇Y P
(3)
which clearly lies in C` P ⊕ P C` . (Furthermore, multiplying with P from either the left or the right yields P ∇Y P P = 0.) The operators &eta, &aster, &xi and &i cause explicit expansion of the symbolic P since the involutions η, ∗ or the anti-involution ξ generally map P to another primitive idempotent and the contraction of P with a dual vector does not even preserve idempotency.
13
Example 10 Following Example 9, we can differentiate the symbol P : > X[{0}] &C P; 0 > X[{1}] &C P; −k e(4 k t) (e1 &v P ) I − k e(4 k t) (P &v e1 ) I >
>
>
>
&eta P;
&xi P;
&aster P;
X[{0}] &i P;
1 1 − I e0 2 2 1 1 + I e0 2 2 1 1 − I e0 2 2 1 I 2
14
5. Matrix Representations Contact with a concrete matrix representation can be made by constructing a matrix basis {mij } for C` . Any Clifford element ω can be expanded as X ω= γij (ω) mij (4) i,j
where the Clifford elements mij satisfy a “total matrix algebra” [1] and serve to define a matrix basis for C` . The complex matrix γ(ω) with entries {γij (ω)} is call the matrix representation of ω with respect to {mij }. In particular, the γ a ≡ γ(ea ) for the ambient basis of V give rise to the usual γ-matrices when the dimension of V is even. The well known relations γ a γ b + γ b γ a = 2 g ab 1 immediately follow from Equations (1) and (4). The command Matrixbasis() returns a table of Clifford elements mij as entries, and matrix basis labels as indices. The choice of {mij } is made by linearly combining the chosen left kernels {αi } to form {αi0 } and right kernels {βi } to form {βi0 } so that α10 = β10 = 1 and P βi0 αj0 P = δij P . This is equivalent to arranging { si ≡ αi0 P } and { r i ≡ P βi0 } to be naturally dual bases for spinors (∈ C` P ) and for dual spinors (∈ P C` ) respectively. Clearly the set { mij ≡ αi0 P βj0 } generate a total matrix algebra: mij mkl = αi0 P βj0 αk0 P βl0 = δjk αi0 P βl0 = δjk mil and since α10 = β10 = 1 we have si = mi1 , r i = m1i and m11 = P . Converting a Clifford element ω into its matrix representation with respect to the chosen matrix basis can be done with the commands convert(ω, Matrix ), convert( ω, column ) or convert( ω, row ). While the first command returns the matrix γ(ω) determined by (4), the second only returns the first column and the third only returns the first row of γ(ω). Therefore, one of the last two commands is preferable if ω is a spinor or dual spinor. Conversely, the command convert( γ, Clifford ) returns the Clifford element ω that γ represents. Here γ can be a square (s × s) matrix such that ω will be computed with the symbolic P explicitly expanded. Otherwise γ is allowed to be a column (s × 1) matrix representing a spinor, or a row (1 × s) matrix representing a dual spinor. Accordingly ω is returned as a linear combination of &v(· · · , P ) or &v(P, · · ·) with P symbolic. 15
The procedure Matrixbasis() is invoked automatically when these conversion facilities are called. Example 11 Following Example 9, examples of conversion between Clifford elements and matrix representations are given: > MB:=Matrixbasis(); MB := table([(2, 1) = e1 &v P, (2, 2) = e(4 k t) &v(e1 , P, e1 ), (1, 1) = P, (1, 2) = e(4 k t) (P &v e1 ) ]) > bcollect(MB[2,2] &v MB[2,2]); >
>
>
>
>
e(4 k t) &v(e1 , P, e1 ) bcollect(MB[2,1] &v MB[1,1] - MB[2,1]); 0 G[0]:=convert(e[0],Matrix); ¸ · −I 0 G0 := 0 I convert(%,Clifford); e0 G[1]:=convert(e[1],Matrix); · ¸ 0 e(−4 k t) G1 := 1 0 convert(%,Clifford); e1
16
>
>
>
> >
>
> >
>
evalm(G[0] &* G[0]);
·
−1 0 0 −1
¸
evalm(G[1] &* G[1]); · (−4 k t) ¸ e 0 0 e(−4 k t) evalm(G[0] &* G[1] + G[1] &* G[0]); · ¸ 0 0 0 0 spinor:=u1*MB[1,1]+u2*MB[2,1]: convert(spinor,column); · ¸ u1 u2 convert(%,Clifford); u1 P + u2 (e1 &v P ) dualspinor:=v1*MB[1,1]+v2*MB[1,2]: convert(dualspinor,row); £ ¤ v1 v2 convert(%,Clifford); v1 P + v2 e(4 k t) (P &v e1 )
17
Example 12 Given a linear or conjugate linear map on spinors Λ : C` P → C` P , it is often convenient to associate Λ with aP transformation matrix Λ when working with P spinor components. If Λ(si ) = j sj Λji (Λij ∈ C), then for any spinor Ψ = i ψi si it follows that X sj Λji ψi i.e. Λ : ψ 7→ Λ ψ Λ(Ψ) = i,j
if Λ is linear, or Λ(Ψ) =
X
i.e. Λ : ψ 7→ Λ ψ ∗
sj Λji ψi∗
i,j
if Λ is conjugate linear. Here ψ is a column matrix consisting of spinor components {ψi }. By exploiting the duality of {r i } and {si } introduced in this section, the associated matrix Λ is determined by Λij P = r i Λ(sj ). The following MAPLE procedure takes such a map as argument and returns the associated transformation matrix: > Ltransmat:=proc(f) >
local P,M,A,i,j,n;
>
M:=Matrixbasis(); # table of the chosen matrix basis
>
n:=sqrt(nops([indices(M)])); # spinor space dimension
>
P:=M[1,1];
>
A:=array(1..n,1..n);
>
for i to n do
>
for j to n do
>
A[i,j]:=coeff(bcollect(M[1,i] &v f(M[j,1])),P)
>
end do
>
end do:
>
eval(A)
>
end proc:
# P is the primitive idempotent
18
Similarly a linear or conjugate P linear map from spinors to dual spinors Ω : C` P → P C` with Ω(si ) = j Ωij r j (Ωij ∈ C), gives rise to the relation Ω(Ψ) = if Ω is linear, or Ω(Ψ) =
X
ψi Ωij r j
i.e. Ω : ψ 7→ ψ T Ω
ψi∗ Ωij r j
i.e. Ω : ψ 7→ ψ ∗T Ω
i,j
X i,j
if Ω is conjugate linear. Here T denotes matrix transposition and so ψ T is a row matrix. The associated matrix Ω is accordingly determined by Ωij P = Ω(si ) sj . Obtaining the associated transformation matrix for such a given map can be encoded into the following MAPLE procedure: > Rtransmat:=proc(f) >
local P,M,A,i,j,n;
>
M:=Matrixbasis();
>
n:=sqrt(nops([indices(M)]));
>
P:=M[1,1];
>
A:=array(1..n,1..n);
>
for i to n do
>
for j to n do
>
A[i,j]:=coeff(bcollect(f(M[i,1]) &v M[j,1]),P)
>
end do
>
end do:
>
eval(A)
>
end proc:
19
6. Spinor Adjoint The spinor adjoint map ‡ with respect to an anti-involution J (J = ξ , ξη , ξ ∗ or ξη ∗ ) is defined by [2] ‡ : C` P −→ P C` Ψ 7−→ Ψ‡ = W ΨJ .
(5)
for some chosen W ∈ P C` P J . Thus if Ψ is a spinor, Ψ‡ is its adjoint. The crucial defining property of ‡ (ω Ψ)‡ = Ψ‡ ω J
(6)
∀ ω ∈ C` , ∀ Ψ ∈ C` P ensures that the spinor inner product ( , ) : C` P × C` P −→ C Φ, Ψ 7−→ (Φ, Ψ) with (Φ, Ψ)P = Φ‡ Ψ
(7)
is invariant under the action Φ 7→ αΦ, Ψ 7→ αΨ where αJ α = 1. This follows since (Φ, Ψ) → (α Φ, α Ψ) = (Φ, αJ α Ψ) = (Φ, Ψ). 6 Given any Clifford element W ∈ P C` P J that defines a spinor adjoint we have also W J ∈ P C` P J which can be used to another spinor adjoint. For J = ξ or ξη W J = πW where the parity π = ±1 depends on the dimension of V . Accordingly the spinor inner product naturally possesses the (anti-)symmetry (Φ, Ψ) = π(Ψ, Φ) for any spinors Φ and Ψ. However if J = ξ ∗ or ξη ∗ we can choose W± = 12 (1 ± J)W ∈ 21 (1 ± J)(P C` P J ) such that W± J = ±W± . W± can be then used to define ‡ and the corresponding spinor product denoted by ( , )± has the Hermitian (anti- )symmetry: (Φ, Ψ)∗± = ±(Ψ, Φ)± . The procedure that generates a choice of spinor adjoint map is Spinoradjoint with the syntax Spinoradjoint( ρ , π ) where for ρ = 1 the anti-involution is ξ, for ρ = 2 the anti-involution is ξη, for ρ = 3 the anti-involution is ξ ∗ and for ρ = 4 the anti-involution is ξη ∗ . π denotes the parity of the adjoint map and may be chosen to be ±1. The second argument will be ignored if ρ is 1 or 2 since only when ρ = 3 or 4 (i.e. J = ξ ∗ or ξη ∗ ) does π need to be specified. (In the case J = ξ or ξη the parity is fixed by the dimension n of the vector space V .) Spinoradjoint The elements α form the subgroup SPIN+ of even elements in the group of invertible elements that maps vectors x ∈ V such that α x α−1 ∈ V . Further information on the subgroups of the Clifford group may be found on page 42 of [1]. 6
20
will display to the user the anti-involution as well as the parity associated with the output adjoint map and return the appropriate unary operator that maps a spinor to its adjoint (dual spinor). Example 13 Following Examples 9 and 10, we can define various spinor adjoint maps: > ‘&ad1‘:=Spinoradjoint(1); ‘(Spinoradjoint) defining spinor adjoint map associated with‘ ‘ >
anti-involution‘, ‘&xi‘, ‘and parity‘, 1, ‘...‘
&ad1 := ψ → SPINADJ(ψ, 1, 1) ‘&ad2‘:=Spinoradjoint(2);
‘(Spinoradjoint) defining spinor adjoint map associated with‘ ‘ > >
anti-involution‘, ‘@‘(‘&eta‘,‘&xi‘), ‘and parity‘, -1, ‘...‘
&ad2 := ψ → SPINADJ(ψ, 2, e1 ) alias(h=h_(t),u1=u1_(t),u2=u2_(t),f1=f1_(t),f2=f2_(t)): ad:=Spinoradjoint(4,1); # Dirac adjoint
‘(Spinoradjoint) defining spinor adjoint map associated with‘ ‘ anti-involution‘, ‘@‘(‘&eta‘,‘&xi‘,‘&aster‘), ‘and parity‘, 1, ‘...‘ > > > > >
ad := ψ → SPINADJ(ψ, 4, 1) ‘&ad‘:=psi -> bcollect(h*ad(psi)): psi:=(u1*exp(I*f1) + u2*exp(I*f2)*e[1]) &v P: # psi is a spinor field with complex components u1*exp(I*f1) and u2*exp(I*f2) coeff(bcollect((&ad psi) &v (I*e[0]) &v psi),P); # get time-component of the Dirac current h (u1 2 + u2 2 e(−4 k t) )
21
As we have seen in Example 13, Spinoradjoint returns a map involving a system reserved procedure SPINADJ. It has the syntax SPINADJ( Ψ , ρ , µ ) for any spinor Ψ ∈ C` P , ρ indicating the adjoint involution J as explained and µ the linear combination the right kernels defined by W = P µ. With a symbolic P and Ψ = σ P for σ an appropriate linear combination of the left kernels, SPINADJ simply computes P µ σ J = W ΨJ = Ψ‡ in accordance with Equations (5) and (6) and returns the result. The assignment H := Spinoradjoint(ρ , π) defines H to be the function name of the chosen spinor adjoint map. A more general spinor adjoint map can be achieved by the rescaling H 0 := ψ -> h*H(ψ)
(8)
with a scalar factor f (which can be a function of the coordinates if defined). h is allowed to be complex in the cases ρ = 1 or 2 (J = ξ or ξη). However h must be real if ρ = 3 or 4 (J = ξ ∗ or ξη ∗ ) in order to preserve the parity π. The conventional definition of spinor adjoint in matrix language follows also from (5). For example consider J = ξ ∗ or ξη ∗ with parity π = +1 leading to the Dirac adjoint. The choice of J is normally taken to be ξ ∗ if the Lorentzian metric has the signature (+, −, −, · · ·), or to be ξη ∗ if the signature is (−, +, +, · · ·) in order to get a (time-like) Dirac current with positive density. Given a matrix basis Hermitian conjugation † P {mij } for C` , the P † ∗ maps a Clifford element ω = i,j γij (ω) mij to ω = i,j γji (ω) mij . A class of Clifford elements C always exists with the properties: C ωJ = ω† C C† = C
∀ ω ∈ C`
(hence C J = C) .
(9) (10)
If m11 = P and W = P C P J is chosen to to define ‡ , it gives rise to a Hermitian symmetric spinor inner product. It follows from (9) that for any Ψ ∈ C` P Ψ‡ = P C ΨJ = P Ψ† C = Ψ† C . (11) P P Writing C = i,j Cij mij and Ψ = i ψi si with the spinor basis {si ≡ mi1 } one can easily transcribe Equation (11) into its matrix form ‡ : ψ 7→ ψ ∗T C .
22
(12)
The matrix versions of Equations (9) and (10) follow as: ² C γ a = γ a∗T C
(13)
C ∗T = C
(14)
where ² = +1 or −1 according to J = ξ ∗ or ξη ∗ . Together with (13) and (14), Equation (12) is just the usual definition of the Dirac adjoint in terms of γmatrices. It is unnecessary to solve (13) and (14) for C in order to construct a spinor adjoint if a matrix basis has been established. It follows from (11) P ‡ † that Φ Ψ = Φ C Ψ for any spinors Φ and Ψ. Using C = i,j Cij mij , the substitution Φ = si and Ψ = sj yields X s‡i sj = m†i1 C mj1 = Ckl m1i mkl mj1 = Cij P k,l
and hence the matrix C as well as the Clifford element C is determined. Example 14 It is instructive to employ the procedure Rtransmat given in Example 12 to compute the “spinor metric matrix” C associated with the spinor adjoint map &ad defined in Example 13. > Cmat:=Rtransmat(‘&ad‘); · ¸ h 0 Cmat := 0 −h e(−4 k t) > C:=convert(Cmat,Clifford); 1 1 C := I h (1 + e(−4 k t) ) e0 − h (−1 + e(−4 k t) ) 2 2 > &eta(&xi(&aster C)) - C; # C has parity +1 0
23
7. Spinor Conjugation Following the definition of the spinor adjoint, we introduce in a similar fashion the spinor conjugation map c on spinors with respect to an involution K (K = η, ∗ or η ∗ in the following) by [2] c
: C` P −→ C` P Ψ 7−→ Ψc = ΨK U
(15)
for some U ∈ P K C` P . This map is defined to satisfy (cf. Equation (6)) (ω Ψ)c = ω K Ψc
(16)
∀ ω ∈ C` , ∀ Ψ ∈ C` P . A choice of spinor conjugation map can be made with the command F := Spinorconjugation( κ ) whose effect is to assign a chosen function name F to the unary operator returned by Spinorconjugation, mapping spinors to spinors. For the parameter κ = 1 the associated involution is η, for κ = 2 the associated involution is ∗ and for κ = 3 the associated involution is η ∗ . The output of Spinorconjugation is a MAPLE map Ψ -> SPINCONJ(Ψ , κ , ν ) where ν is a linear combination of the left kernels such that the selected U is given by U = ν P . For Ψ = σ P the call F (Ψ) returns the spinor conjugation of Ψ. (The system reserved procedure SPINCONJ exploits the algorithm Ψc = σ K ν P suggested from Equations (15) and (16).) Since P K C` P is 1dimensional, implying that U is fixed up to a complex factor, the (optional) subsequent command F 0 := ψ -> f *F (ψ) (17) with an arbitrary scalar factor f leads to another spinor conjugation map named F 0 . This enables the user to explicitly normalise the spinor conjugation map. The charge conjugation map is a transformation between complex spinors. In a Lorentzian spacetime, complex spinors can carry representations of the electromagnetic U(1) gauge group describing electrically charged fields. The transformed spinor will then describe a field with opposite charge. Such a mapping is induced by c with K = ∗ if the metric has signature (−, +, +, · · ·) and is induced by c with K = η ∗ if the signature is (+, −, −, · · ·). To compare with the definition of charge conjugation in matrix language note that if 24
{mij } is a matrix basis for C` then so is {mK ij }. The simplicity of C` guarantees the existence of a Clifford element B (unique up to a complex factor) that relates the two matrix bases {mij } and {mij K } via a similarity transformation: mij K = B mij B−1 . (18) P This implies, for K = ∗, η ∗ and any Clifford element ω = i,j γij (ω) mij , P P −1 ∗ that ω K = i,j γij∗ (ω) mK ij = i,j γij (ω) B mij B . This can be expressed as ωK B = B ω] (19) P where ] is defined by ω ] = i,j γij∗ (ω) mij for any ω ∈ C` . If m11 = P and P {si = mi1 } then Ψ = i ψi si for any spinor Ψ ∈ C` P . If U = P K B P is chosen to define the spinor conjugation map it then follows from (19) that Ψc = ΨK B P = B Ψ] .
(20)
Therefore the matrix equivalent of charge conjugation is c
: ψ 7→ Bψ ∗
with the square matrix B and column matrix ψ given by B = P and Ψ = i ψi si . Together with ²B γ a∗ = γ a B
(21) P i,j
Bij mij (22)
(² = +1 or −1 according to K = ∗ or η ∗ ) derived from (19), Equation (21) is just the definition of charge conjugation in terms of γ-matrices and spinor components. Given U , (20) can be used to compute the corresponding matrix B: m1i mcj1 = si † sj c = Bij P . It can be shown that BK B is a real number hence by scaling, one can always arrange BK B = ±1 corresponding to B ∗ B = ±1 and U K U = ±P . This is the standard normalisation condition (achieved in LUCY by scaling the charge conjugation map using (17)) ensuring that the norm of the Dirac current is preserved under charge conjugation.
25
Example 15 Following Example 14, a choice of the charge conjugation is made and the corresponding “charge conjugation matrix” B , with respect to the chosen matrix basis, computed using Ltransmat described in Example 12. > cc:=Spinorconjugation(2); ‘(Spinorconjugation) defining spinor conjugation map associated with‘ ‘ > >
>
>
involution‘, ‘&aster‘, ‘...‘
cc := ψ → SPINCONJ(ψ, 2, e1 ) ‘&c‘:=psi -> bcollect(exp(2*k*t)*cc(psi)): Bmat:=Ltransmat(‘&c‘); · ¸ 0 e(−2 k t) Bmat := e(2 k t) 0 B:=convert(Bmat,Clifford); B := e(2 k t) e1 bcollect(B &v &aster B); # B &v &aster B is normalised to 1 1
26
8. Spinor Covariant Derivative A spinor covariant derivative with respect to any tangent vector field Y , denoted by SY , is a type-preserving directional derivative on spinors [1], [3]. Of particular interest is the unique SY having the properties: SY (ωΨ) = ∇Y ω Ψ + ω SY Ψ
(Leibnitz rule over Clifford product)
(23)
Y (Φ, Ψ) = (SY Φ, Ψ) + (Φ, SY Ψ) (compatibility with spinor adjoint) (24) ∀ ω ∈ C` , ∀ Φ, Ψ ∈ C` P where ∇ is the Levi-Civita connection on Clifford elements. If the inner product above is fixed by the anti-involution J = ξ or ξη these equations serve to determine SY uniquely. For the case J = ξ ∗ or ξη ∗ , one may additionally require compatibility with charge conjugation: (SY Ψ)c = SY Ψc .
(25)
Although the usual argument leading to the existence and the explicit construction of such a SY is made with matrix representations and in an orthonormal basis, this is unnecessary [1], [4]. LUCY identifies SY with the map: SY : C` P −→ C` P (26) Ψ 7−→ SY Ψ = (∇Y Ψ) P + (iY λ) Ψ for some (in general complex) covector field λ. (23) is satisfied immediately. Using the definition of the spinor adjoint (5) and the spinor invariant inner product (7), the compatibility requirement (24) completely determines λ by 2 (iY λ)W = P ∇Y W P J
(27)
if J = ξ or ξη, but only fixes the real part of λ: iY (λ + λ∗ )W = P ∇Y W P J
(28)
if J = ξ ∗ or ξη ∗ . In these cases, the imaginary part of λ can be determined by demanding (25), which yields iY (λ − λ∗ )U = −P K ∇Y U P
(29)
where K = ∗ or η ∗ and (15) has been used. To establish contact with the usual local matrix representation of SY one considers local dual bases, {Xa } for TM and {ea } for T∗ M in which 27
the metric components are constant e.g. orthonormal bases. It follows that the Levi-Civita connection coefficients Γabc = gad Γd bc (cf. Equation (2)) are antisymmetric in their first two indices: Γabc + Γbac = 0 .
(30)
With the introduction of the real bivectors Σa ≡
1 Γbca [eb , ec ] 8
(31)
where [ω, σ] ≡ ω σ − σ ω ∀ ω, σ ∈ C` , it is straightforward to verify the relation ∇Xa ec = [Σa , ec ] and more generally ∇Xa eI = [Σa , eI ]
(32)
using (30). Here I denotes a multi-index and eI is any element of the Clifford basis { 1, ea , eb , · · · , ea eb , · · · }. Since g ab are we can find a matrix P constants a a basis {mij } for C` such that the e = i,j γij mij give rise to a set of a constant γ-matrices {γ }. This implies that the two bases {eI } and {mij } for C` are linearly related with some constant coefficients. Hence from (32) ∇Xa mij = [Σa , mij ] . P For any Clifford element ω = i,j γij (ω) mij it follows that X ∇X a ω = Xa (γij (ω)) mij + [Σa , ω] .
(33)
(34)
i,j
In such a frame and matrix basis, a “canonical spinor adjoint” corresponding to a constant spinor metric matrix C satisfying (13) and (14) can be introduced yielding the Clifford element W , also with a constant matrix representation. Σa are real bivectors so Σa K = Σa for K = ∗ or η ∗ and Σa J = −Σa for J = ξ , ξη , ξ ∗ or ξη ∗ . However the scalar hΣa i defined by hΣa iP = P Σa P is not necessarily real since P is complex in general. It then follows from (34) and noticing W ∈ P C` P J that P ∇Xa W P J = P [Σa , W ] P J = P Σa W + (P Σa W J )J = (hΣa i + hΣa iJ ) W .
(35)
If J = ξ or ξη then hΣa iJ = hΣa i and one can feed (35) into (27) to obtain the relation λ = hΣa i ea . (36) 28
Otherwise if J = ξ ∗ or ξη ∗ then hΣa iJ = hΣa i∗ implying iXa (λ + λ∗ ) = hΣa i + hΣa i∗
(37)
by virtue of (28) and (35). If a “canonical charge conjugation” is introduced with constant charge conjugation matrix B satisfying (22) then the corresponding U is also associated with a constant matrix representation. Therefore for J = ξ ∗ or ξη ∗ one further calculates that P K ∇Xa U P = P K [Σa , U ] P = (P Σa U K )K − U Σa P = −(hΣa i − hΣa i∗ ) U
(38)
using the property U ∈ P K C` P , K = ∗ or η ∗ . Substituting (38) into (29) gives iXa (λ − λ∗ ) = hΣa i − hΣa i∗ . (39) Interestingly, by adding or subtracting (37) and (39) one obtains Equation (36) again. Thus λ can be used to set up a “canonical spinor covariant derivative” with respect to any canonical spinor adjoint and charge conjugation map: First adopt the spinor basis {si ≡Pmi1 } such that any spinor Ψ ∈ C` P (P = m11 ) can be written as Ψ = i ψi si and exploit (34) to calculate the spinor covariant derivative of Ψ as follows: SXa Ψ = (∇Xa Ψ) P + (iXa λ) Ψ X = Xa (ψi ) si + [Σa , Ψ] P + (iXa λ) Ψ i X = Xa (ψi ) si + Σa Ψ − Ψ P Σa P + (iXa λ) Ψ i X = Xa (ψi ) si + Σa Ψ i
where the cancellation in the last step follows from (36). With [M , N ] denoting M N −N M for any square matrices M and N , the above equation gives rise to the canonical representation SXa : ψ 7→ Xa (ψ) +
1 Γbca [γ b , γ c ] ψ 8
where the column matrices ψ and Xa (ψ) respectively contain the spinor components {ψi } and the direction derivatives {Xa (ψi )}.
29
In LUCY the procedure Spinorderiv generates the spinor covariant derivative map. Consider first the situation where a frame has been chosen in which the metric components are constants. The command Spinorderiv() returns a binary map which maps any tangent vector field Y and spinor Ψ to SY Ψ with the canonical SY . The corresponding covector field λ is computed from Equation (36) and, if required, is returned by calling SPINCONNEX(). Example 16 The Dirac operator with contributions from the mass term µ, the electromagnetic potential A (a real covector field), and the electric charge q is defined [1], [5] by Dirac = ea SXa + iqA + µ with respect to any coframe {ea } and dual frame {Xa }. Hence Dirac Ψ = 0 is the Dirac equation for a complex spinor field Ψ, minimally coupled to a U(1) gauge field. For simplicity the next illustration evaluates the Dirac equation on a 2-dimensional flat spacetime using Cartesian coordinates. > Cliffordsetup(0..1,{(0,0)=-1,(1,1)=1},e,X,{e[0]=d(t),e[1]=d(x)}): > knls:=Spinorsetup(P)[1]; knls := [1, e1 ] > alias(f1=f1_(t,x),f2=f2_(t,x)): > comps:=[f1,f2]: > psi:=convert(zip((x,y)->x*y,comps,knls),‘+‘) &v P; ψ := f1 P + f2 (e1 &v P ) > convert(psi,column); · ¸ f1 f2 > ‘&S‘:=Spinorderiv(); # The canonical spinor covariant derivative &S := bcollect@((Y, ψ) → (Y &C ψ) &v P ) > # Dirac operator: > DIRAC:=(psi,mu,qA)->(convert([seq(e[i] &v (X[{i}] &S > >
psi),i=0..1)],‘+‘) + I*qA &v psi - mu*psi): qA:=Q*x*e[0]: # Interaction with a uniform electric field
30
>
two
phi:=DIRAC(psi,mu,qA): # The Dirac equation phi=0 leads to
>
coupled 1st order differential equations convert(phi,column); · ¸ ∂ ∂ −( ∂t f1 ) I + ( ∂x f2 ) + Q x f1 − µ f1 ∂ ∂ ( ∂t f2 ) I + ( ∂x f1 ) − Q x f2 − µ f2 xi:=DIRAC(phi,-mu,qA): # The induced two 2nd order differential mxi:=convert(xi,column): # equations decouple if Q=0 mxi[1,1];
>
∂ ∂ ∂ 2 2 2 −( ∂t 2 f1 ) − 2 I Q x ( ∂t f1 ) − Q f2 + ( ∂x2 f1 ) + Q x f1 − µ f1 mxi[2,1];
> >
> >
2
2
> > >
>
>
2
2
∂ ∂ ∂ 2 2 2 −( ∂t 2 f2 ) − 2 I Q x ( ∂t f2 ) + ( ∂x2 f2 ) + Q f1 + Q x f2 − µ f2 alias(v1=v1_(t,x),v2=v2_(t,x),u1=u1_(t,x),u2=u2_(t,x)): ccomps:=[u1+I*v1,u2+I*v2]: # Make a spinor with complex components chi:=bcollect(convert(zip((x,y)->x*y,ccomps,knls),‘+‘) &v P); χ := (u2 + v2 I) (e1 &v P ) + (u1 + v1 I) P convert(chi,column); · ¸ u1 + v1 I u2 + v2 I ‘&ad‘:=Spinoradjoint(4,1): # The Dirac adjoint
‘(Spinoradjoint) defining spinor adjoint map associated with‘ ‘ anti-involution‘, ‘@‘(‘&eta‘,‘&xi‘,‘&aster‘), ‘and parity‘, 1, ‘...‘ > > > > >
# A spinor inner product: sprod:=(phi,psi)->coeff(bcollect(&ad(phi) &v psi),P): # The Dirac current with positive density: curr:=convert([seq(sprod(chi,-I*e[{i}] &v chi)*e[i],i=0..1)],‘+‘); curr := (u2 2 + v2 2 + u1 2 + v1 2 ) e0 + (−2 u2 v1 + 2 v2 u1 ) e1
Example 17 This is an example yielding a spinor connection with a non-zero covector λ on a 2-dimensional flat spacetime with a uniformly accelerating orthonormal coframe { e0 = σdτ, e1 = dσ }. 31
> >
>
>
>
Cliffordsetup(0..1,{(0,0)=-1,(1,1)=1},e,X, {e[0]=sigma*d(tau),e[1]=d(sigma)}); e0 {d(τ ) = , d(σ) = e1 } σ Spinorsetup(P=1/2*(1+e[0] &v e[1])); [[1, e0 ], [1, e0 ]] ‘&S‘:=Spinorderiv(); 1 (Y &i e0 ) ψ &S := (Y, ψ) → bcollect(((Y &C ψ) &v P ) − ) 2 σ lambda:=SPINCONNEX(); 1 e0 λ := − 2 σ
32
For a situation in which the metric components in the ambient frame are not constant (due either to a choice of coordinates or the presence of curvature), [6], a more flexible facility for computing the spinor covariant is available. The binary map SY takes any tangent vector field Y and spinor Ψ to SY Ψ, the unique spinor covariant derivative compatible with a specified spinor inner product and charge conjugation operation. It is returned by calling Spinorderiv with the syntax: Spinorderiv( ρ , h , π , κ , f ) . The covector λ used in defining this SY is also available by calling SPINCONNEX( ρ , h , π , κ , f ) . Using the same correspondence employed for Spinoradjoint, the integer ρ indicates the choice of adjoint anti-involution. h is a real factor which scales the spinor adjoint via Equation (8). The third to fifth arguments (π , κ and f ) are not required if ρ = 1 or 2 (Equation (27) is sufficient to determine λ). Otherwise the parity π = ±1 and the involution ∗ for κ = 2 or η ∗ for κ = 3 must be chosen in order that λ can be determined using Equations (28) and (29). f is a scalar chosen to normalise the charge conjugation map via Equation (17). Note that both h and f are allowed to be any functions of the coordinates as described in Sections 6 and 7. If no modification to the default spinor adjoint (or charge conjugation) map is intended, the value of h (or f ) should be 1. Example 18 Following from Examples 9 – 15, this example illustrates how to get the Spinor covariant differential operator compatible with the spinor adjoint and charge conjugation defined in the previous examples. A particular solution to a massless Dirac equation is also presented for arbitrary constants a1 , a2 , b1 and b2 : > ‘&S‘:=Spinorderiv(4,h,1,2,exp(2*k*t)); Ã ! ∂ h) (Y &i e0 ) ψ 1 ( ∂t &S := (Y, ψ) → bcollect ((Y &C ψ) &v P ) + 2 h > > > >
u1:=a1/sqrt(h)*exp(-k*t): u2:=a2/sqrt(h)*exp(+k*t): f1:=b1: f2:=b2: 33
>
psi;
>
a1 e(−k t) e(b1 I) P a2 e(k t) e(b2 I) (e1 &v P ) √ √ + h h Q0:=X[{0}] &S psi;
>
a1 k e(−k t+b1 I) P a2 k e(k t+b2 I) (e1 &v P ) √ √ Q0 := − − h h Q1:=X[{1}] &S psi;
a2 k e(k t+b2 I) P I a1 e(3 k t+b1 I) k (e1 &v P ) I √ √ − h h > # massless Dirac equation satisfied: > bcollect(e[0] &v Q0 + e[1] &v Q1); 0 > phi:=&c psi: # charge conjugate of psi satisfies the same equation > bcollect( e[0] &v (X[{0}] &S phi) + e[1] &v (X[{1}] &S phi) ); 0 Q1 :=
Acknowledgements JS would like to thank Lancaster University for kind hospitality. This work was partially supported by a Human Capital and Mobility Programme of the European Union (RWT). CW is grateful to the Committee of ViceChancellors and Principals for an Overseas Research Studentship and to Lancaster University for a Studentship and Peel Award.
34
References [1] I M Benn, R W Tucker, An Introduction to Spinors and Geometry with Applications in Physics, (Adam Hilger) (1987) [2] J Schray, C Wang, A Constructive Definition for Bilinear Forms on Spinors, Advances in Applied Clifford Algebra 6 (2) 151–158 (1996) [3] R W Tucker, in Clifford Algebras and their Applications in Mathematical Physics, Eds. J S R Chisholm, A K Common, NATO ASI Series (C) 183 (1985) [4] W L Bade, H Jehle, An Introduction to Spinors, Rev. Mod. Phys. 25 714–728 (1953) [5] I M Benn, R W Tucker, The Dirac Equation in Exterior Form, Commun. Math. Phys. 98 53–63 (1985) [6] T Dray, C A Manogue, J Schray, R W Tucker, C Wang, The construction of spinor fields on manifolds with smooth degenerate metrics, Journal of Mathematical Physics 37 3882–3896 (1996)
35
List of Procedures
Procedure name
Description
Page(s)
&aster &C &eta &i &v &xi APPLYP bcollect Cliffordbasis Cliffordsetup convert/Clifford convert/column convert/down convert/Matrix convert/row convert/up expandP FILTER Matrixbasis METRIC RIEMCONNEX SPINADJ SPINCONJ SPINCONNEX Spinoradjoint Spinorconjugation Spinorderiv Spinorsetup type/&v
Complex conjugation Levi-Civita covariant differential Main Clifford algebra involution Interior product (Contraction operator) Clifford algebra product Main Clifford algebra anti-involution Internal usage Collects and simplifies coefficients of bases Ambient Clifford basis excluding unity Initialisation procedure for Clifford algebra Converts to a Clifford element Converts to a column matrix representation Lowers indices Converts to a matrix representation Converts to a row matrix representation Raises indices Expands symbolic primitive Internal usage Total matrix basis for Clifford algebra Internal usage Table of Levi-Civita connection components Output map from Spinoradjoint Output map from Spinorconjugation Covector used in Spinorderiv Spinor adjoint Spinor conjugation Levi-Civita spinor covariant differential Initialisation procedure for spinor modules Internal usage
4 9 4 6 3 4
36
4,12 4,5 3,5,7,8 15 15 5 15 15 5 12 15 9 22 24 30,33 20 24 30,33 11,12
